home *** CD-ROM | disk | FTP | other *** search
/ ShareWare OnLine 2 / ShareWare OnLine Volume 2 (CMS Software)(1993).iso / cad / opampdem.zip / CF.LIB < prev    next >
Text File  |  1993-03-02  |  7KB  |  244 lines
  1. * Library of National Semiconductor Corp. CURRENT-FEEDBACK  
  2. * Macromodels.  Version 2.5
  3. *
  4. * This library of macromodels is being supplied to users as
  5. * an aid to circuit designs.  While it reflects reasonably 
  6. * close similarity to the actual device in terms of
  7. * performance, it is not suggested as a replacement for
  8. * breadboarding.  Simulation should be used as a supplement
  9. * to traditional lab testing.
  10. *
  11. * Users should very carefully note the following factors
  12. * regarding these models:
  13. *
  14. * -- Model performance in general will reflect typical
  15. * baseline specs for a given device, and certain aspects of
  16. * performance may not be modeled fully.
  17. *
  18. * -- While reasonable care has been taken in their
  19. * preparation, we cannot be responsible for correct
  20. * application on any and all computer systems.
  21. *
  22. * -- Model users are hereby notified that these models are
  23. * supplied "as is", with no direct or implied responsibility
  24. * on the part of National Semiconductor for their operation
  25. * within a customer circuit or system.  Further, National
  26. * Semiconductor reserves the right to change these models
  27. * without prior notice.
  28. *
  29. * -- In all cases, the current data sheet information for a
  30. * given real device is your final design guideline, and is
  31. * the only actual performance guarantee.  For further
  32. * technical information, refer to individual device data
  33. * sheets.
  34. *
  35. ***********************Modeled and tested*******************
  36. *Supply voltage dependant input offset voltage (Vos). 
  37. *Temperature dependant input offset voltage (TCVos). 
  38. *Supply voltage dependant input bias current (Ib+ & Ib- PSR). 
  39. *Temperature dependant input bias current (TCIb+ & TCIb-). 
  40. *Input voltage dependant input bias current (Ib- CMRR). 
  41. *Non-inverting input resistance.  
  42. *Asymmetrical output swing. 
  43. *Output short circuit current (Isc). 
  44. *Supply voltage dependant supply current. 
  45. *Quiescent and dynamic supply current. 
  46. *Input voltage dependant input slew rate. 
  47. *Input voltage dependant output slew rate. 
  48. *Multiple poles and zeros in open-loop transimpedance (Zt). 
  49. *Supply voltage dependant input buffer impedance. 
  50. *Supply voltage dependant open-loop voltage gain (Avol). 
  51. *Feedback resistance dependant bandwidth. 
  52. *Accurate small-signal pulse response. 
  53. *Large-signal pulse response. 
  54. *DC and AC common mode rejection ratio (CMRR). 
  55. *DC and AC power supply rejection ratio (PSRR). 
  56. *White and 1/f voltage noise (en). 
  57. *White and 1/f current noise (in). 
  58. *********************Modeled but not tested*****************
  59. *Asymmetrical output slew rate. 
  60. *Input common mode input range. 
  61. *Supply voltage dependant input slew rate. 
  62. ***************************Not modeled**********************
  63. *Third-order large signal effects.
  64. *Self heating effects.
  65. *
  66. * Your feedback and suggestions on these (and future) models
  67. * will be appreciated.
  68. *
  69. * Models developed by:
  70. * David Hindi
  71. * National Semiconductor       For information on the models, contact:
  72. * 2900 Semiconductor Dr.       Linear Applications    
  73. * Santa Clara, CA 95052        (408) 721-3877 
  74. * M/S C2500                     
  75. * FAX (408) 721-7321           For ordering information, contact:
  76. *                              Customer Response Center
  77. *                              (408) 721-4902
  78. * ---------------------------------------------------------
  79. *//////////////////////////////////////////////////////////
  80. *LM6181 CURRENT FEEDBACK OP-AMP MACRO-MODEL
  81. *//////////////////////////////////////////////////////////
  82. *
  83. * connections:      non-inverting input
  84. *                   |   inverting input
  85. *                   |   |   positive power supply
  86. *                   |   |   |   negative power supply
  87. *                   |   |   |   |   output
  88. *                   |   |   |   |   |
  89. *                   |   |   |   |   |
  90. .SUBCKT LM6181      1   2  99  50  40
  91. *
  92. *Features:                          (TYP.)
  93. *High bandwidth =                   100MHz
  94. *High slew rate =                 2000V/uS
  95. *Current Feedback Topology
  96. *NOTE:  Due to the addition of PSRR effects, model must be operated
  97. *       with symetrical supply voltages.  To avoid this limitation 
  98. *       and disable the PSRR effects, see EOS below.
  99. *
  100. ****************INPUT STAGE************** 
  101. *
  102. GI1 99  5 POLY(1) 99 50 243.75U 2.708E-6
  103. GI2  4 50 POLY(1) 99 50 243.75U 2.708E-6
  104. FI1 99  5 VA3 100
  105. FI2  4 50 VA4 100
  106. Q1  50  3 5 QPN
  107. Q2  99  3 4 QNN 
  108. GR1  5  6 5 6 2.38E-4
  109. *^4.2K noiseless resistor
  110. C1   6 99 .468P
  111. GR2  4  7 4 7 2.38E-4
  112. *^4.2K noiseless resistor
  113. C2   7 50 .468P
  114. GR3 99  8 99 8 1.58E-3
  115. *^633ohm noiseless resistor
  116. V1  99 10 .3
  117. RE1 10 30 130
  118. D1  30  8 DX
  119. GR4 50  9 50 9 1.58E-3
  120. *^633ohm noiseless resistor
  121. V2  11 50 .3
  122. RE2 11 31 150
  123. D2   9 31 DX
  124. Q3   8  6 2 QNI
  125. Q4   9  7 2 QPI
  126. DS1  3 12 DY
  127. VA3 12  5 0
  128. DS2 13  3 DY
  129. VA4  4 13 0
  130. GR6  1 99 1 99 5E-8
  131. *^20MEG noiseless resistor
  132. GR7  1 50 1 50 5E-8
  133. *^20MEG noiseless resistor
  134. GB1  1 99 POLY(2) 99 50 56  0 -1.2E-6 4E-8 1E-3
  135. FN1  1  0 V18 1
  136. GB2 99  2 POLY(3) 99 50 1 49 55 0 18.5E-6 -1.5E-7 -1E-7 -1E-6
  137. FN2  2  0 V17 1
  138. EOS  3  1 POLY(5) 99 50 45  0 47 0 57 0 59 61 -2.8E-3 9.3E-5 1 1 1 1
  139. *To run on asymetrical supplies, change to 0.................^.^
  140. CIN1 1  0 2P
  141. CIN2 2  0 3.75P
  142. *
  143. **************SECOND STAGE**************
  144. *
  145. I3  99 50 4.47M
  146. R8  99 49 7.19K
  147. R9  49 50 7.19K
  148. V3  99 16 1.7
  149. D3  15 16 DX
  150. D4  17 15 DX
  151. V4  17 50 2.0
  152. EH  99 98 99 49 1
  153. G1  98 15 POLY(2) 99 8 50 9 0 1.58E-3 1.58E-3
  154. *Fp1 = 27.96 KHz
  155. R5  98 15 2.372MEG
  156. C3  98 15 2.4P
  157. * 
  158. ***************POLE STAGE*************** 
  159. *
  160. *Fp=250MHz
  161. G2  98 20 15 49 1E-3
  162. R14 98 20 1K
  163. C4  98 20 .692P
  164. *
  165. ***************POLE STAGE*************** 
  166. *
  167. *Fp=250 MHz
  168. G3  98 21 20 49 1E-3
  169. R15 98 21 1K
  170. C5  98 21 .692P
  171. *
  172. ***************POLE STAGE*************** 
  173. *
  174. *Fp=275 MHz
  175. G4  98 22 21 49 1E-3
  176. R16 98 22 1K
  177. C6  98 22 .5787P
  178. *
  179. ***************POLE STAGE*************** 
  180. *
  181. *Fp=500 MHz
  182. G5  98 23 22 49 1E-3
  183. R17 98 23 1K
  184. C7  98 23 .3183P
  185. *
  186. ***************PSRR STAGE***************
  187. *
  188. G10  0 45 99 0 1.413E-4
  189. L3  44 45 26.53U
  190. R25 44  0 10
  191. G11  0 47 50 0 1.413E-4
  192. L4  46 47 2.27364U
  193. R26 46  0 10
  194. *
  195. ************THERMAL EFFECTS*************
  196. *
  197. I12  0 55 1
  198. R27  0 55 10  TC=3.453E-3 7.93E-5
  199. I13  0 56 1E-3
  200. R28  0 56 1.5 TC=9.303E-4 8.075E-5
  201. I14  0 57 1E-3
  202. R29  0 57 3.34 TC=3.111E-3
  203. *
  204. ************* NOISE SOURCES*************
  205. *
  206. V15 58  0 .1
  207. D9  58 59 DN
  208. R30 59  0 726.4
  209. V16 60  0 .1
  210. D10 60 61 DN
  211. R31 61  0 726.4
  212. V17 62  0 0
  213. R32 62  0 73.6
  214. V18 63  0 0
  215. R33 63  0 1840
  216. *
  217. **************OUTPUT STAGE**************
  218. *
  219. F6  99 50 VA7 1
  220. F5  99 35 VA8 1
  221. D7  36 35 DX
  222. VA7 99 36 0
  223. D8  35 99 DX
  224. E1  99 37 99 23 1
  225. VA8 37 38 0
  226. R35 38 40 50
  227. V5  33 40 5.3V
  228. D5  23 33 DX
  229. V6  40 34 5.3V
  230. D6  34 23 DX
  231. CF1 40  2 2.1P
  232. *
  233. ***************MODELS USED**************
  234. *
  235. .MODEL QNI NPN(IS=1E-14 BF=10E4 VAF=62.9 KF=6.7E-14)
  236. .MODEL QPI PNP(IS=1E-14 BF=10E4 VAF=62.9 KF=6.7E-14)
  237. .MODEL QNN NPN(IS=1E-14 BF=10E4 VAF=62.9 KF=4.13E-13)
  238. .MODEL QPN PNP(IS=1E-14 BF=10E4 VAF=62.9 KF=4.13E-13)
  239. .MODEL DX  D(IS=1E-15)
  240. .MODEL DY  D(IS=1E-17)
  241. .MODEL DN  D(KF=1.667E-9 AF=1 XTI=0 EG=.3)
  242. *
  243. .ENDS
  244.